Contingut

# Funcions financeres, segona part

Per a accedir a aquesta ordre...

Insereix ▸ Funció ▸ categoria Finances

Torna a Funcions financeres, primera part

Segueix a Funcions financeres, tercera part

## CAPITACUM

Retorna l'interès acumulat pagat per a un període d'inversió amb un tipus d'interès constant.

#### Sintaxi

CAPITACUM(Tipus; NPer; VA; I; F; Tipus)

Tipus és el tipus d'interès periòdic.

NPer és el període de pagament amb el nombre total de períodes. NPER també pot ser un valor que no sigui enter.

VA és el valor actual en la seqüència de pagaments.

I és el primer període.

F és l'últim període.

Tipus és la data de venciment del pagament al principi o al final de cada període.

#### Exemple

Quins són els beneficis si el tipus d'interès anual és del 5,5% durant 36 mesos? El valor efectiu és de 15.000 unitats monetàries. El benefici es calcula entre el desè i el divuitè període. La data de venciment és al final del període.

=CAPITACUM(5,5%/12;36;15000;10;18;0) = -3669,74 unitats monetàries. El benefici entre el desè i el divuitè període és de 3669,74 unitats monetàries.

## CAPITACUM_ADD

Calcula el reemborsament acumulat d'un préstec durant un període.

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per a obtenir resultats basats en els estàndards internacionals.

#### Sintaxi

CAPITACUM_ADD(Tipus; NPer; VA; PeríodeInicial; PeríodeFinal; Tipus)

Tipus és el tipus d'interès de cada període.

NPer és el nombre total de períodes de pagament. El tipus i NPER han de fer referència a la mateixa unitat, i per tant s'han de calcular de manera anual o mensual.

VA és el valor actual.

PeríodeInicial és el primer període de pagament per al càlcul.

PeríodeFinal és l'últim període de pagament del càlcul.

Tipus és el venciment d'un pagament al final de cada període (Tipus = 0) o a l'inici del període (Tipus = 1).

#### Exemple

Es pren el préstec hipotecari següent d'una llar:

Tipus: 9,00% anual (9% / 12 = 0,0075), durada: 30 anys (períodes de pagament = 30 * 12 = 360), VNA: 125.000 unitats monetàries.

Quant haureu de pagar el segon any de la hipoteca (per exemple, dels períodes 13 al 24)?

=CAPITACUM_ADD(0,0075;360;125000;13;24;0) retorna -934,1071

El primer mes reemborsareu la quantitat següent:

=CAPITACUM_ADD(0,0075;360;125000;1;1;0) retorna -68,27827

## DURADAM

Calcula la durada de Macauley modificada d'un valor de renda fixa en anys.

#### Sintaxi

MDURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Cupó és el tipus d'interès nominal anual (tipus d'interès del cupó)

Rendiment és el rendiment anual del títol.

Freqüència és el nombre de pagaments d'interessos per any (1, 2 o 4).

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Es compra un títol l'01/01/2000; la data de venciment és l'01/01/2006. El tipus d'interès nominal és del 8%. El rendiment és del 9,0%. L'interès es paga cada mig any (la freqüència és 2). Utilitzant el càlcul d'interessos sobre saldos diaris (base 3), quina és la durada modificada?

=MDURATION("2001-01-01"; "2006-01-01"; 0.08; 0.09; 2; 3) returns 4.02 years.

## LNR

Retorna l'amortització lineal d'un actiu durant un període. L'import de la depreciació és constant durant el període de depreciació.

#### Sintaxi

LNR(Cost; ValorResidual; Vida)

Cost és el cost inicial d'un actiu.

Valor residual és el valor d'un actiu al final de la depreciació.

Vida és el període de depreciació que determina el nombre de períodes en la depreciació de l'actiu.

#### Exemple

L'equipament d'oficina amb un cost inicial de 50.000 unitats monetàries es depreciarà en 7 anys. El valor al final de la depreciació ha de ser de 3.500 unitats monetàries.

=LNR(50000;3,500;84) = 553,57 unitats monetàries. La depreciació periòdica mensual de l'equipament d'oficina és de 553,57 unitats monetàries.

## MONEDADE

Converteix una cotització que s'ha donat com a fracció decimal en un nombre decimal.

#### Sintaxi

MONEDADE(MonedaEnFracció; Fracció)

MonedaEnFracció és un nombre expressat com a fracció decimal.

Fracció és un nombre enter que s'utilitza com a denominador de la fracció decimal.

#### Exemple

=MONEDADE(1,02;16) és 1 i 2/16. Això retorna 1,125.

=MONEDADE(1,1;8) és 1 i 1/8. Això retorna 1,125.

## MONEDAFR

Converteix una cotització que s'ha donat com a nombre decimal en una fracció decimal mixta.

#### Sintaxi

MONEDAFR(MonedaDecimal; Fracció)

MonedaDecimal és un nombre decimal.

Fracció és un nombre enter que s'utilitza com a denominador de la fracció decimal.

#### Exemple

=MONEDAFR(1,125;16) converteix a setzens. El resultat és 1,02 per 1 més 2/16.

=MONEDAFR(1,125;8) converteix a vuitens. El resultat és 1,1 per 1 més 1/8.

## NOMINAL

Calcula el tipus d'interès nominal anual a partir de la taxa equivalent i el nombre de períodes compostos anuals.

#### Sintaxi

NOMINAL(TaxaEquivalent; NPerA)

TaxaEquivalent és la taxa anual equivalent

NPerA és el nombre de pagaments periòdics d'interessos cada any.

#### Exemple

Quin és l'interès nominal anual d'una taxa anual equivalent del 13,5% si es fan 12 pagaments cada any?

=NOMINAL(13,5%;12) = 12,73%. El tipus d'interès nominal anual és del 12,73%.

## NOMINAL_ADD

Calcula el tipus d'interès nominal anual a partir del valor efectiu i el nombre de pagaments d'interessos per any.

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per a obtenir resultats basats en els estàndards internacionals.

#### Sintaxi

NOMINAL_ADD(TaxaEquivalent; NPerA)

TaxaEquivalent és la taxa d'interès anual equivalent.

NPerA el nombre de pagaments d'interessos per any.

#### Exemple

Quin és el tipus d'interès nominal per a una taxa anual equivalent del 5,3543% i un pagament trimestral?

=NOMINAL_ADD(5,3543%;4) retorna 0,0525 o 5,25%.

## PDURATION

Calcula el nombre de períodes que es necessiten perquè una inversió tingui el valor desitjat.

#### Sintaxi

PDURATION(Rate; PV; FV)

Tipus és una constant. El tipus d'interès s'ha de calcular per a tota la durada (període de durada). El tipus d'interès per període es calcula dividint el tipus d'interès per la durada calculada. El tipus intern d'una anualitat s'ha d'introduir com a Tipus/12.

VA és el valor actual. El valor efectiu és el dipòsit d'efectiu o el valor actual d'efectiu actual d'un pagament en espècie. Com a valor de dipòsit s'ha d'introduir un valor positiu; el dipòsit no ha de ser 0 o <0.

VF és el valor esperat. El valor futur determina el valor (futur) desitjat del dipòsit.

#### Exemple

Amb un tipus d'interès del 4,75%, un valor efectiu de 25.000 unitats monetàries i un valor futur d'1.000.000 d'unitats monetàries, s'obté una durada de 79,49 períodes de pagament. El pagament periòdic és el quocient que resulta del valor futur i la durada, en aquest cas 1.000.000/79,49=12.850,20.

## PMT

Retorna el pagament periòdic d'una anualitat amb tipus d'interès constant.

#### Sintaxi

PMT(Rate; NPer; PV [ ; [ FV ] [ ; Type ] ])

Tipus és el tipus d'interès periòdic.

NPer és el nombre de períodes durant els quals es paga l'anualitat.

VA és el valor actual (valor efectiu) en una seqüència de pagaments.

VF (opcional) és el valor desitjat (valor futur) que s'ha d'aconseguir al final dels pagaments periòdics.

Tipus (opcional) és la data de venciment dels pagaments periòdics. Tipus=1 és el pagament a l'inici del període i Tipus=0 és el pagament al final de cada període.

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els segueixi. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

#### Exemple

Quins són els pagaments periòdics amb un tipus d'interès anual de l'1,99% si el temps de pagament és de 3 anys i el valor efectiu és de 25.000 unitats monetàries? Hi ha 36 mesos com a 36 períodes de pagament, i el tipus d'interès per període de pagament és de 1,99%/12.

=PMT(1,99%/12;36;25000) = -715,96 unitats monetàries. El pagament mensual periòdic és de 715,96 unitats monetàries.

## PMTIACUM

Calcula els pagaments dels interessos acumulats, és a dir, l'interès total d'una inversió que es basa en un tipus d'interès constant.

#### Sintaxi

PMTIACUM(Tipus; Nper; VA; I; F; Tipus)

Tipus és el tipus d'interès periòdic.

NPer és el període de pagament amb el nombre total de períodes. NPER també pot ser un valor que no sigui enter.

VA és el valor actual en la seqüència de pagaments.

I és el primer període.

F és l'últim període.

Tipus és la data de venciment del pagament al principi o al final de cada període.

#### Exemple

Quins són els pagaments d'interessos amb un tipus d'interès anual del 5,5%, un període de pagaments mensuals durant 2 anys i un valor efectiu actual de 5.000 unitats monetàries? El període d'inici és el 4t i el període de finalització és el 6è. El pagament venç a l'inici de cada període.

=PMTIACUM(5,5%/12;24;5000;4;6;1) = -57,54 unitats monetàries. Els pagaments d'interessos entre el 4t i el 6è període són de 57,54 unitats monetàries.

## PMTIACUM_ADD

Calcula l'interès acumulat d'un període.

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per a obtenir resultats basats en els estàndards internacionals.

#### Sintaxi

PMTIACUM_ADD(Tipus; NPer; VA; PeríodeInicial; PeríodeFinal; Tipus)

Tipus és el tipus d'interès de cada període.

NPer és el nombre total de períodes de pagament. El tipus i NPER han de fer referència a la mateixa unitat, i per tant s'han de calcular de manera anual o mensual.

VA és el valor actual.

PeríodeInicial és el primer període de pagament per al càlcul.

PeríodeFinal és l'últim període de pagament del càlcul.

Tipus és el venciment d'un pagament al final de cada període (Tipus = 0) o a l'inici del període (Tipus = 1).

#### Exemple

Es pren el préstec hipotecari següent d'una llar:

Tipus: 9,00% anual (9% / 12 = 0,0075), durada: 30 anys (NPER = 30 * 12 = 360), VA: 12.5000 unitats monetàries.

Quin interès heu de pagar el segon any de la hipoteca (per exemple, dels períodes 13 al 24)?

=PMTIACUM_ADD(0,0075;360;125000;13;24;0) retorna -11135,23.

Quin interès heu de pagar el primer mes?

=PMTIACUM_ADD(0,0075;360;125000;1;1;0) retorna -937,50.

## PMTP

Retorna el pagament d'una inversió d'un cert període que es basa en pagaments periòdics i constants i un tipus d'interès constant.

#### Sintaxi

PPMT(Rate; Period; NPer; PV [ ; FV [ ; Type ] ])

Tipus és el tipus d'interès periòdic.

Període és el període d'amortització. P = 1 per al primer període i P = NPer per a l'últim període.

NPer és el nombre total de períodes durant els quals es paga l'anualitat.

VA és el valor actual en una seqüència de pagaments.

VF (opcional) és el valor (futur) desitjat.

Tipus (opcional) defineix la data de venciment. F = 1 per al pagament al principi d'un període i F = 0 per a al pagament al final d'un període.

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els segueixi. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

#### Exemple

Quin és el pagament mensual periòdic amb un tipus d'interès anual del 8,75% durant un període de 3 anys? El valor efectiu és de 5.000 unitats monetàries i sempre es paga al principi d'un període. El valor futur és de 8.000 unitats monetàries.

=PMTP(8,75%/12;1;36;5000;8000;1) = -350,99 unitats monetàries.

## PREU

Calcula el valor de mercat d'un valor de renda fixa que té un valor a la par de 100 unitats monetàries com a funció del rendiment previst.

#### Sintaxi

PRICE(Settlement; Maturity; Rate; Yield; Redemption; Frequency [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Tipus és el tipus d'interès nominal anual (tipus d'interès del cupó)

Rendiment és el rendiment anual del títol.

Reemborsament és el valor de reemborsament per 100 unitats monetàries de valor a la par.

Freqüència és el nombre de pagaments d'interessos per any (1, 2 o 4).

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Es compra un títol el 15/02/1999; la data de venciment és el 15/11/2007. El tipus d'interès nominal és del 5,75%. El rendiment és del 6,5%. El valor de reemborsament és de 100 unitats monetàries. L'interès es paga cada mig any (la freqüència és 2). Amb un càlcul amb base 0, el preu és el següent:

=PRICE("1999-02-15"; "2007-11-15"; 0.0575; 0.065; 100; 2; 0) returns 95.04287.

## PREUDESC

Calcula el preu per 100 unitats monetàries de valor a la par d'un títol que no comporta interessos.

#### Sintaxi

PRICEDISC(Settlement; Maturity; Discount; Redemption [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Descompte és el descompte d'un títol com a percentatge.

Reemborsament és el valor de reemborsament per 100 unitats monetàries de valor a la par.

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Es compra un títol el 15/02/1999; la data de venciment és l'1/03/1999. El descompte en percentatge és del 5,25%. El valor de reemborsament és 100. En fer el càlcul amb base 2, el descompte del preu és:

=PRICEDISC("1999-02-15"; "1999-03-01"; 0.0525; 100; 2) returns 99.79583.

## PREULLETRAT

Calcula el preu d'una lletra del tresor per 100 unitats monetàries.

#### Sintaxi

PREULLETRAT(Liquidació; Venciment; Descompte)

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Descompte és el percentatge de descompte en adquirir un títol.

#### Exemple

Data de liquidació: 31 de març del 1999, data de venciment: 1 de juny del 1999, descompte: 9%.

El preu de la lletra del tresor s'obté de la manera següent:

=TBILLPRICE("1999-03-31";"1999-06-01"; 0.09) returns 98.45.

## PREUVEN

Calcula el preu per 100 unitats monetàries de valor a la par d'un títol, que paga interessos a la data de venciment.

#### Sintaxi

PRICEMAT(Settlement; Maturity; Issue; Rate; Yield [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Emissió és la data d'emissió del títol.

Tipus és el tipus d'interès del títol a la data d'emissió.

Rendiment és el rendiment anual del títol.

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Data de liquidació: 15 de febrer del 1999, data de venciment: 3 d'abril del 1999, data d'emissió: 11 de novembre del 1998. Tipus d'interès: 6,1%, rendiment: 6,1%, base: 30/360 = 0.

El preu es calcula de la manera següent:

=PRICEMAT("1999-02-15";"1999-04-13";"1998-11-11"; 0.061; 0.061;0) returns 99.98449888.

## QLLETRAT

Calcula la rendibilitat anual d'una lletra del tresor.El dia de la data de liquidació es compra una lletra del tresor i es ven per tot el valor a la par el dia de la data de venciment, en el mateix any. Es resta un descompte del preu de compra.

#### Sintaxi

QLLETRAT(Liquidació; Venciment; Descompte)

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Descompte és el percentatge de descompte en comprar el títol.

#### Exemple

Data de liquidació: 31 de març del 1999, data de venciment: 1 de juny del 1999, descompte: 9,14%.

La rendibilitat de la lletra del tresor que correspon al títol s'obté de la manera següent:

=TBILLEQ("1999-03-31";"1999-06-01"; 0.0914) returns 0.094151 or 9.4151 per cent.

## RENDIM

Calcula el rendiment d'un títol.

#### Sintaxi

YIELD(Settlement; Maturity; Rate; Price; Redemption; Frequency [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Tipus és el tipus d'interès anual.

Preu és el preu (preu de compra) del títol per 100 unitats monetàries de valor a la par.

Reemborsament és el valor de reemborsament per 100 unitats monetàries de valor a la par.

Freqüència és el nombre de pagaments d'interessos per any (1, 2 o 4).

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Es compra un títol el 15/02/1999. Venç el 15/11/2007. El tipus d'interès és del 5,75%. El preu és de 95,04287 unitats monetàries per 100 unitats de valor a la par, el valor de reemborsament és de 100 unitats. L'interès es paga cada mig any (freqüència = 2) i la base és 0. Quin és el rendiment?

=YIELD("1999-02-15"; "2007-11-15"; 0.0575 ;95.04287; 100; 2; 0) returns 0.065 or 6.50 per cent.

## RENDIMDESC

Calcula el rendiment anual d'un títol que no comporta interessos.

#### Sintaxi

YIELDDISC(Settlement; Maturity; Price; Redemption [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Preu és el preu (preu de compra) del títol per 100 unitats monetàries de valor a la par.

Reemborsament és el valor de reemborsament per 100 unitats monetàries de valor a la par.

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Es compra un títol que no comporta interessos el 15/02/1999. Venç l'01/03/1999. El preu és de 99,795 unitats monetàries per 100 unitats de valor a la par, el valor de reemborsament és de 100 unitats. La base és 2. Quin és el rendiment?

=YIELDDISC("1999-02-15"; "1999-03-01"; 99.795; 100; 2) returns 0.052823 or 5.2823 per cent.

## RENDIMLLETRAT

Calcula el rendiment d'una lletra del tresor.

#### Sintaxi

RENDIMLLETRAT(Liquidació; Venciment; Preu)

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Preu és el preu (preu de compra) d'una lletra del tresor per 100 unitats monetàries de valor a la par.

#### Exemple

Data de liquidació: 31 de març del 1999, data de venciment: 1 de juny del 1999, preu: 98,45 unitats monetàries.

El rendiment de la lletra del tresor s'obté de la manera següent:

=TBILLYIELD("1999-03-31";"1999-06-01"; 98.45) returns 0.091417 or 9.1417 per cent.

## RENDIMVEN

Calcula el rendiment anual d'un títol, l'interès del qual es paga a la data de venciment.

#### Sintaxi

YIELDMAT(Settlement; Maturity; Issue; Rate; Price [; Basis])

Liquidació és la data de compra del títol.

Venciment és la data en què venç el títol (caduca).

Emissió és la data d'emissió del títol.

Tipus és el tipus d'interès del títol a la data d'emissió.

Preu és el preu (preu de compra) del títol per 100 unitats monetàries de valor a la par.

La Base es tria d'una llista d'opcions i indica com s'ha de calcular l'any.

Base | Càlcul
--- | ---
0 or missing | Mètode americà (NASD), 12 mesos de 30 dies cadascun
1 | Nombre exacte de dies en mesos, nombre exacte de dies en un any
2 | Nombre exacte de dies del mes, l'any té 360 dies
3 | Nombre exacte de dies del mes, l'any té 365 dies
4 | Mètode europeu, 12 mesos de 30 dies cadascun

#### Exemple

Es compra un títol el 15/03/1999. Venç el 03/11/1999. La data d'emissió era el 08/11/1998. El tipus d'interès és del 6,25%, el preu és de 100,0123 unitats. La base és 0. Quin és el rendiment?

=YIELDMAT("1999-03-15"; "1999-11-03"; "1998-11-08"; 0.0625; 100.0123; 0) returns 0.060954 or 6.0954 per cent.

## TIRR

Calcula la taxa interna de rendibilitat modificada d'una sèrie d'inversions.

#### Sintaxi

TIRR (Valors;Inversió;TaxaReinv)

Valors correspon a la matriu o a la referència de la cel·la per a les cel·les el contingut de les quals es correspongui amb els pagaments.

Inversió és el tipus d'interès de les inversions (els valors negatius de la matriu)

TipusReinv: el tipus d'interès de la reinversió (els valors positius de la matriu)

#### Exemple

Si suposem que el contingut de la cel·la A1 = -5, A2 = 10, A3 = 15 i A4 = 8, un valor d'inversió de 0,5 i un valor de reinversió de 0,1, el resultat es 94,16%.

## VNA

Returns the present value of an investment based on a series of periodic cash flows and a discount rate. To get the net present value, subtract the cost of the project (the initial cash flow at time zero) from the returned value.

If the payments take place at irregular intervals, use the XNPV function.

#### Sintaxi

NPV(Taxa; Number 1 [; Number 2 [; … [; Number 254]]])

Taxa és la taxa de descompte d'un període.

Number 1; Number 2; … ; Number 254 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Exemple

What is the net present value of periodic payments of 10, 20, 30 and -5 currency units with a discount rate of 8.75%. At time zero the costs were paid as -40 currency units.

=NPV(8.75%;10;20;30;-5) = 45.86 currency units. The net present value is the returned value minus the initial costs of 40 currency units, therefore 5.86 currency units.

Torna a Funcions financeres, primera part

Segueix a Funcions financeres, tercera part

Funcions per categoria